home *** CD-ROM | disk | FTP | other *** search
/ Atari Mega Archive 2 / Atari Mega Archive CD - Volume 2.iso / 8bit / cislib_a / fileli.xmo < prev    next >
Text File  |  1995-04-22  |  7KB  |  327 lines
  1. (* FILELIB.I - Routines to allow the use of standard ATARI I/O calls in KYAN 
  2.    Pascal programs. 
  3.  
  4.    IOCBUsed  - If called immediately following a pascal Reset or Rewrite call 
  5.               this function will return the number of the IOCB that was used. 
  6.    FileOpen  - Exactly like the ATARI Basic OPEN command. 
  7.    FileClose - Exactly like the ATARI Basic CLOSE command. 
  8.    FileGet   - Replace the parameters REC and RECLEN with the name and length 
  9.                of your record and this routine will read one record from the 
  10.                file. 
  11.    FilePut   - The inverse of FileGet. 
  12.    FileNote  - Exactly like the ATARI Basic NOTE command. 
  13.    FilePoint - Exactly like the ATARI Basic POINT command. 
  14.  
  15.    I don't recommend that you mix these routines with the standard Pascal 
  16.    I/O routines, though CLOSE might be useful.  They were written for use in a 
  17.    small database program the DEMANDED true random access files.  Use them with 
  18.    care as none of the protection provided by Pascal is present here.        *) 
  19.  
  20.  
  21. Function IOCBUsed : Integer; 
  22.  
  23. Begin 
  24. #a 
  25.  
  26.      LDA $2E        ;Get IOCB # 
  27.      LSR A          ;Divide by 16 
  28.      LSR A 
  29.      LSR A 
  30.      LSR A 
  31.      LDY #3         ;Store in IOCBnum 
  32.      STA (SP),Y 
  33.      INY 
  34.      LDA #0 
  35.      STA (SP),Y 
  36.  
  37. # 
  38. End; (* IOCBUsed *) 
  39.  
  40.  
  41. Procedure FileOpen(IOCBnum,IOdir,Auxbyte : Integer; 
  42.                    Var FileName : String15); 
  43.  
  44. Begin 
  45. #a 
  46.  
  47. ICHID EQU $0340 
  48. ICDNO EQU $0341 
  49. ICCMD EQU $0342 
  50. ICSTA EQU $0343 
  51. ICBAL EQU $0344 
  52. ICBAH EQU $0345 
  53. ICPTL EQU $0346 
  54. ICPTH EQU $0347 
  55. ICBLL EQU $0348 
  56. ICBLH EQU $0349 
  57. ICAX1 EQU $034A 
  58. ICAX2 EQU $034B 
  59. ICAX3 EQU $034C 
  60. ICAX4 EQU $034D 
  61. ICAX5 EQU $034E 
  62. ICAX6 EQU $034F 
  63.  
  64. CIOV  EQU $E456 
  65.  
  66. ; T   = LSB of 'FileName' 
  67. ; T+1 = MSB of 'FileName' 
  68. ; T+2 = LSB of AuxByte 
  69. ; T+3 = MSB of AuxByte (Unused) 
  70. ; T+4 = LSB of IOdir 
  71. ; T+5 = MSB of IOdir (Unused) 
  72. ; T+6 = LSB of IOCBnum 
  73. ; T+7 = MSB of IOCBnum (Unused) 
  74.  
  75.      TXA            ;Save X register 
  76.      PHA 
  77.      LDX #7         ;Copy heap 
  78.      LDY #10 
  79. CL1  LDA (SP),Y 
  80.      STA T,X 
  81.      DEY 
  82.      DEX 
  83.      BPL CL1 
  84.      LDA T+6        ;Get IOCB # 
  85.      ASL A          ;Multiply by 16 
  86.      ASL A 
  87.      ASL A 
  88.      ASL A 
  89.      TAX            ;Move to X register 
  90.      LDA #3         ;Open command 
  91.      STA ICCMD,X 
  92.      LDA T          ;Filename address 
  93.      STA ICBAL,X 
  94.      LDA T+1 
  95.      STA ICBAH,X 
  96.      LDA T+4        ;Data direction 
  97.      STA ICAX1,X 
  98.      LDA T+2        ;Aux byte 
  99.      STA ICAX2,X 
  100.      JSR CIOV       ;Do the I/O 
  101.      PLA            ;Restore X register 
  102.      TXA 
  103.  
  104. # 
  105. End; (* FileOpen *) 
  106.  
  107.  
  108. Procedure FileClose(IOCBnum : Integer); 
  109.  
  110. Begin 
  111. #a 
  112.  
  113. ; T   = LSB of IOCBnum 
  114. ; T+1 = MSB of IOCBnum (Unused) 
  115.  
  116.      TXA            ;Save X register 
  117.      PHA 
  118.      LDX #1         ;Copy heap 
  119.      LDY #4 
  120. CL2  LDA (SP),Y 
  121.      STA T,X 
  122.      DEY 
  123.      DEX 
  124.      BPL CL2 
  125.      LDA T          ;Get IOCB # 
  126.      ASL A          ;Multiply by 16 
  127.      ASL A 
  128.      ASL A 
  129.      ASL A 
  130.      TAX            ;Move to X register 
  131.      LDA #12        ;Close command 
  132.      STA ICCMD,X 
  133.      JSR CIOV       ;Do the I/O 
  134.      PLA            ;Restore X register 
  135.      TAX 
  136.  
  137. # 
  138. End; (* FileClose *) 
  139.  
  140.  
  141. Procedure FileGet(IOCBnum : Integer; 
  142.                   Var Rec : RecType; 
  143.                   RecLen  : Integer); 
  144.  
  145. Begin 
  146. #a 
  147.  
  148. ; T   = LSB of Length 
  149. ; T+1 = MSB of Length 
  150. ; T+2 = LSB of 'Word' 
  151. ; T+3 = MSB of 'Word' 
  152. ; T+4 = LSB of IOCBnum 
  153. ; T+5 = MSB of IOCBnum (Unused) 
  154.  
  155.      TXA            ;Saved X register 
  156.      PHA 
  157.      LDX #5         ;Copy heap 
  158.      LDY #8 
  159. CL3  LDA (SP),Y 
  160.      STA T,X 
  161.      DEY 
  162.      DEX 
  163.      BPL CL3 
  164.      LDA T+4        ;Get IOCB # 
  165.      ASL A          ;Multiply by 16 
  166.      ASL A 
  167.      ASL A 
  168.      ASL A 
  169.      TAX            ;Move to X register 
  170.      LDA #7         ;Get record command 
  171.      STA ICCMD,X 
  172.      LDA T+2        ;Data address 
  173.      STA ICBAL,X 
  174.      LDA T+3 
  175.      STA ICBAH,X 
  176.      LDA T          ;Data length 
  177.      STA ICBLL,X 
  178.      LDA T+1 
  179.      STA ICBLH,X 
  180.      JSR CIOV       ;Do the I/O 
  181.      PLA            ;Restore X register 
  182.      TAX 
  183.  
  184. # 
  185. End; (* FileGet *) 
  186.  
  187.  
  188. Procedure FilePut(IOCBnum : Integer; 
  189.                   Var Rec : RecType; 
  190.                   RecLen  : Integer); 
  191.  
  192. Begin 
  193. #a 
  194.  
  195. ; T   = LSB of Length 
  196. ; T+1 = MSB of Length 
  197. ; T+2 = LSB of 'Word' 
  198. ; T+3 = MSB of 'Word' 
  199. ; T+4 = LSB of IOCBnum 
  200. ; T+5 = MSB of IOCBnum 
  201.  
  202.      TXA            ;Save X register 
  203.      PHA 
  204.      LDX #5         ;Copy heap 
  205.      LDY #8 
  206. CL4  LDA (SP),Y 
  207.      STA T,X 
  208.      DEY 
  209.      DEX 
  210.      BPL CL4 
  211.      LDA T+4        ;Get IOCB # 
  212.      ASL A          ;Multiply by 16 
  213.      ASL A 
  214.      ASL A 
  215.      ASL A 
  216.      TAX            ;Move to X register 
  217.      LDA #11        ;Put record command 
  218.      STA ICCMD,X 
  219.      LDA T+2        ;Data address 
  220.      STA ICBAL,X 
  221.      LDA T+3 
  222.      STA ICBAH,X 
  223.      LDA T          ;Data length 
  224.      STA ICBLL,X 
  225.      LDA T+1 
  226.      STA ICBLH,X 
  227.      JSR CIOV       ;Do the I/O 
  228.      PLA            ;Restore X register 
  229.      TAX 
  230.  
  231. # 
  232. End; (* FilePut *) 
  233.  
  234.  
  235. Procedure FileNote(IOCBnum : Integer; 
  236.                    Var Sector,Byte : Integer); 
  237.  
  238. Begin 
  239. #a 
  240.  
  241. ; T   = LSB of 'Byte' 
  242. ; T+1 = MSB of 'Byte' (Unused) 
  243. ; T+2 = LSB of 'Sector' 
  244. ; T+3 = MSB of 'Sector' 
  245. ; T+4 = LSB of IOCBnum 
  246. ; T+5 = MSB of IOCBnum (Unused) 
  247.  
  248.      TXA            ;Save X register 
  249.      PHA 
  250.      LDX #5         ;Copy heap 
  251.      LDY #8 
  252. CL5  LDA (SP),Y 
  253.      STA T,X 
  254.      DEY 
  255.      DEX 
  256.      BPL CL5 
  257.      LDA T+4        ;Get IOCB # 
  258.      ASL A          ;Multiply by 16 
  259.      ASL A 
  260.      ASL A 
  261.      ASL A 
  262.      PHA            ;Save for later 
  263.      TAX            ;Move to X register 
  264.      LDA #38        ;Note command 
  265.      STA ICCMD,X 
  266.      JSR CIOV       ;Do the I/O 
  267.      PLA            ;Get IOCB # X 16 
  268.      TAX            ;Move to X register 
  269.      LDY #0 
  270.      LDA ICAX5,X    ;Get LSB of Byte 
  271.      STA (T),Y 
  272.      LDA ICAX3,X    ;Get LSB of Sector 
  273.      STA (T+2),Y 
  274.      INY 
  275.      LDA #0         ;MSB of Byte 
  276.      STA (T),Y 
  277.      LDA ICAX4,X    ;Get MSB of Sector 
  278.      STA (T+2),Y 
  279.      PLA            ;Restore X register 
  280.      TAX 
  281.  
  282. # 
  283. End; (* FileNote *) 
  284.  
  285.  
  286. Procedure FilePoint(IOCBnum,Sector,Byte : Integer); 
  287.  
  288. Begin 
  289. #a 
  290.  
  291. ; T   = LSB of Byte 
  292. ; T+1 = MSB of Byte (Unused) 
  293. ; T+2 = LSB of Sector 
  294. ; T+3 = MSB of Sector 
  295. ; T+4 = LSB of IOCBnum 
  296. ; T+5 = MSB of IOCBnum (Unused) 
  297.  
  298.      TXA            ;Save X register 
  299.      PHA 
  300.      LDX #5         ;Copy heap 
  301.      LDY #8 
  302. CL6  LDA (SP),Y 
  303.      STA T,X 
  304.      DEY 
  305.      DEX 
  306.      BPL CL6 
  307.      LDA T+4        ;Get IOCB # 
  308.      ASL A          ;Multiply by 16 
  309.      ASL A 
  310.      ASL A 
  311.      ASL A 
  312.      TAX            ;Move to X register 
  313.      LDA #37        ;Point command 
  314.      STA ICCMD,X 
  315.      LDA T+2        ;LSB of Sector 
  316.      STA ICAX3,X 
  317.      LDA T+3        ;MSB of Sector 
  318.      STA ICAX4,X 
  319.      LDA T          ;LSB of Byte 
  320.      STA ICAX5,X 
  321.      JSR CIOV       ;Do the I/O 
  322.      PLA            ;Restore X register 
  323.      TAX 
  324.  
  325. # 
  326. End; (* FilePoint *) 
  327. TTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTTT